Hot Topic (More than 25 Replies) Библиотеки для симуляторов (Прочитано 250 раз)
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Библиотеки для симуляторов
16.06.2012 :: 23:13:06
Post Tools
Предлагаю в этой теме сконцентрировать всё, что касается симуляторных библиотек.

К админам просьба - подцепить эту тему в топе на постоянку. Она не должна упасть в забвение...
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Советские NPN
Ответ #1 - 16.06.2012 :: 23:28:57
Post Tools
В качестве первого взноса в фонд - библиотечка советских транзюков.

Для начала - список того, что есть. Только сорри - проблема с кодировкой. Оно так ко мне прибежало - потому названия транзисторов видны, а весь остальной текст пох#рился.

Но, полагаю, если приспичит кому - то разберётся.

Потихоньку скину файлы на какой-нибудь правильный ресурс (где не пропадает) - а пока кому надо, запрашивайте, я конкретный тип скину текстом в сюда...

Итак, поехали:

Цитата:
*                     ЃЁЇ®«па­лҐ ва ­§Ёбв®ал
*
*    p-n-p       і     n-p-n       і    p-n-p       і   n-p-n
*ДДДДДДДДДДДДДДДДЕДДДДДДДДДДДДДДДДДЕДДДД
ДДДДДДДДДДДЕДДДДДДДДДДДДДДДДДД
*2’202Ђ, Ѓ, ‚, ѓ і2’215Ђ, Ѓ, ‚, ѓ  іЉ’208Љ          і
*2’203„          і2T312A, Ѓ, B     іЉ’351Ђ          і
*2’214Ђ, Ѓ, ‚, ѓ і2’315Ђ, …, „, €  іЉ’363Ђ          і
*2’313Ѓ          і2’316Ѓ, „        іЉ’364Ђ, Ѓ, ‚    і
*2’326Ѓ          і2’324Ђ, Ѓ, ‚,    іЉ’375Ђ, Ѓ       і
*2’360Ђ, Ѓ, ѓ    і        ѓ, „, …  і’‘3103Ђ-1,      іЉ’312Ѓ
*2’363Ѓ          і2’325Ѓ           іЉ’3107Ђ,Ѓ,‚,ѓ,  і
*2’364Ђ-2, Ѓ-2   і2’354Ђ           і  „,…,ѓ…,€,Љ,‹  іЉ’315Ђ,Ѓ,‚,ѓ,
*     ‚-2        і2’355Ђ           і                і  „,…,ѓ…,€
*2’370Ђ-1        і2’368Ѓ           іЉ’830Ђ, Ѓ, ‚, ѓ іЉ’316b
*2’3107Ђ, …, €, Љі2’371Ђ           і                іЉ’385ЂЊ-2
*2’3108Ђ, Ѓ, ‚   і2’384AM-2        іЉ’836Ђ, Ѓ, ‚    іЉ’399Ђ
*2’626Ђ          і2’385Ђ           і                іЉ’3102Ђ, Ѓ, ЃЊ,
*2’632Ђ          і2’388Ђ           і                і          ‚, ѓ, …
*2’639Ѓ          і2’397            і                іЉ’3117Ђ
*2’644Ѓ          і2’399Ђ           і                іЉ’608Ђ, Ѓ
*2’708           і2’3102Ђ, Ѓ, …    і                іЉ’630Ђ, Ѓ, ‚,
*2’709           і2’3117Ђ          і                і       ѓ, „, …
*2’818Ђ          і2’504            і                іЉ’635Ѓ
*2’825Ђ          і2’505            і                іЉ’642Ђ-2
*2’830Ђ          і2’602Ђ, Ѓ        і                іЉ’653Ѓ
*                і2’625Ђ, Ѓ        і                іЉ’815ѓ
*                і2’629Ђ           і                іЉ’819Ђ, Ѓ, ‚
*                і2’630Ђ, Ѓ, ‚,    і                іЉ’831Ђ, Ѓ, ‚
*                і        ѓ, „     і                іЉ’841Ђ
*                і2’638Ђ           і                іЉ’847Ђ
*                і2’646Ђ           і                іЉ’866Ђ
*                і2’819Ђ, Ѓ, ‚, ѓ  і                іЉ’880Ђ
*                і2’827Ђ           і                іЉ’926Ђ
*                і2’831Ђ           і                і
*                і2’921Ђ           і                і
*                і2T939A           і                і
*


  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
ЗАПРОС: LM317L и LM337L
Ответ #2 - 16.06.2012 :: 23:34:55
Post Tools
Хочется модельки LM317L и LM337L - на толстые (в мощных корпусах) в сети можно нарыть, а вот на ТО-92 что-то не отыскивается.

У кого есть?
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
zEROID
Гуру
*****
Вне Форума


Играю на гитаре
и паяю с детства
:-)

Сообщений: 3021
Местоположение: Москва
Зарегистрирован: 24.12.2009
Re: Библиотеки для симуляторов
Ответ #3 - 17.06.2012 :: 10:10:31
Post Tools
"§Ёбв®ал" - вот это особенно сильно!
  

(Вложенный файл удалён)
Наверх
IP записан
 
abcetc
Разбирающийся
****
Вне Форума


GTLab - forever!

Сообщений: 809
Зарегистрирован: 18.02.2007
Re: Библиотеки для симуляторов
Ответ #4 - 18.06.2012 :: 05:01:21
Post Tools
Реально §Ёбв®ал  Очень довольный

Попробую выковярять совковые диоды и стабилитроны, если кому нужны
« Последняя редакция: 18.06.2012 :: 05:01:55 от abcetc »  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #5 - 18.06.2012 :: 22:30:45
Post Tools
Спайс-моделька TL431 с адекватной частотной коррекцией:
http://www.ti.com/litv/zip/slvm071a

Правда, меня не порадовало отсутствие в модели обратного диода - надо добавлять самому...
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #6 - 26.07.2012 :: 10:34:12
Post Tools
Взято вот тут: http://forum.gtlab.net/cgi-bin/yabb2/YaBB.pl?num=1124494648/360#366

Цитата:
.MODEL KP302A NJF VTO=-2.0 BETA=0.0025 LAMBDA=0.03 RD=1 RS=1 IS=1.145e-13 CGD=4e-12 CGS=9e-12 PB=0.5 B=1.2 KF=4e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP302B NJF VTO=-3.2 BETA=0.0023 LAMBDA=0.03 RD=1 RS=1 IS=1.145e-13 CGD=4e-12 CGS=9e-12 PB=0.5 B=1 KF=3e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP302G NJF VTO=-5.0 BETA=0.002 LAMBDA=0.03 RD=1 RS=1 IS=1.145e-13 CGD=4e-12 CGS=9e-12 PB=0.5 B=1 KF=3e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP302W NJF VTO=-6.0 BETA=0.0015 LAMBDA=0.03 RD=1 RS=1 IS=1.145e-13 CGD=4e-12 CGS=9e-12 PB=0.5 B=1 KF=3e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP303A NJF VTO=-0.9 BETA=0.0016 LAMBDA=0.02 RD=36 RS=30 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=9e-17 AF=1.4 FC=0.5 TNOM=27
.MODEL KP303B NJF VTO=-0.8 BETA=0.0016 LAMBDA=0.02 RD=36 RS=30 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=1e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP303E NJF VTO=-4.0 BETA=0.0007 LAMBDA=0.025 RD=20 RS=15 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=1e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP303G NJF VTO=-2.6 BETA=0.001 LAMBDA=0.025 RD=22 RS=17 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=7e-17 AF=1.3 FC=0.5 TNOM=27
.MODEL KP303D NJF VTO=-2.0 BETA=0.0011 LAMBDA=0.025 RD=25 RS=19 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=9e-17 AF=1 FC=0.5 TNOM=27
.MODEL KP303I NJF VTO=-1.6 BETA=0.0014 LAMBDA=0.025 RD=30 RS=25 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=3e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP303J NJF VTO=-0.6 BETA=0.0017 LAMBDA=0.015 RD=40 RS=32 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=3e-16 AF=1 FC=0.5 TNOM=27
.MODEL KP303W NJF VTO=-1.4 BETA=0.0013 LAMBDA=0.025 RD=36 RS=30 IS=1.145e-13 CGD=2e-12 CGS=6e-12 PB=0.5 B=1.2 KF=9e-17 AF=1 FC=0.5 TNOM=27
.MODEL KP307A NJF VTO=-1.5 BETA=0.0023 LAMBDA=0.015 RD=20 RS=15 IS=1.145e-13 CGD=1.5e-12 CGS=5e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KP307B NJF VTO=-2.2 BETA=0.002 LAMBDA=0.015 RD=20 RS=15 IS=1.145e-13 CGD=1.5e-12 CGS=5e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KP307W NJF VTO=-2.5 BETA=0.0018 LAMBDA=0.015 RD=20 RS=15 IS=1.145e-13 CGD=1.5e-12 CGS=5e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KP307G NJF VTO=-2.7 BETA=0.0015 LAMBDA=0.015 RD=20 RS=15 IS=1.145e-13 CGD=1.5e-12 CGS=5e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KP307D NJF VTO=-3.2 BETA=0.0012 LAMBDA=0.015 RD=20 RS=15 IS=1.145e-13 CGD=1.5e-12 CGS=5e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KP307E NJF VTO=-0.9 BETA=0.0027 LAMBDA=0.015 RD=20 RS=15 IS=1.145e-13 CGD=1.5e-12 CGS=5e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KPS104A NJF VTO=-0.4 BETA=0.002 LAMBDA=0.005 RD=20 RS=15 IS=1.145e-13 CGD=1.2e-12 CGS=4e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KPS104V NJF VTO=-0.9 BETA=0.0015 LAMBDA=0.008 RD=20 RS=15 IS=1.145e-13 CGD=1.2e-12 CGS=4e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KPS104G NJF VTO=-1.5 BETA=0.001 LAMBDA=0.01 RD=20 RS=15 IS=1.145e-13 CGD=1.2e-12 CGS=4e-12 PB=0.5 B=1 KF=5e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL KP103E PJF VTO=-0.8 BETA=0.0008 LAMBDA=0.02 RD=40 RS=1 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.7 FC=0.5 TNOM=27
.MODEL KP103I PJF VTO=-1.5 BETA=0.00068 LAMBDA=0.02 RD=40 RS=1 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.7 FC=0.5 TNOM=27
.MODEL KP103J PJF VTO=-1.2 BETA=0.00072 LAMBDA=0.02 RD=40 RS=1 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.7 FC=0.5 TNOM=27
.MODEL KP103K PJF VTO=-2.0 BETA=0.0006 LAMBDA=0.02 RD=40 RS=1 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.7 FC=0.5 TNOM=27
.MODEL KP103L PJF VTO=-2.5 BETA=0.00055 LAMBDA=0.02 RD=40 RS=1 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.7 FC=0.5 TNOM=27
.MODEL KP103M PJF VTO=-3.2 BETA=0.0005 LAMBDA=0.02 RD=40 RS=1 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.7 FC=0.5 TNOM=27
.MODEL K504HT1A PJF VTO=-1.6 BETA=0.00058 LAMBDA=0.02 RD=13 RS=10 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL K504HT1B PJF VTO=-2.5 BETA=0.00046 LAMBDA=0.02 RD=13 RS=10 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL K504HT1W PJF VTO=-4.0 BETA=0.00036 LAMBDA=0.02 RD=13 RS=10 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL K504HT3A PJF VTO=-1.5 BETA=0.0008 LAMBDA=0.02 RD=10 RS=7 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL K504HT3B PJF VTO=-2.6 BETA=0.0007 LAMBDA=0.02 RD=10 RS=7 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL K504HT3W PJF VTO=-4.2 BETA=0.0006 LAMBDA=0.02 RD=10 RS=7 IS=1.2195e-11 CGD=8e-12 CGS=2e-11 PB=1 B=1 KF=1e-18 AF=0.5 FC=0.5 TNOM=27
.MODEL 2P903A NJF (VTO=-5.0 BETA=0.03 LAMBDA=0.02 RD=0.5 RS=0.5 CGS=15E-012 CGD=13E-011)
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
lart
Разбирающийся
****
Вне Форума



Сообщений: 1334
Зарегистрирован: 15.04.2005
Re: Библиотеки для симуляторов
Ответ #7 - 19.08.2012 :: 06:17:11
Post Tools
Три модели для J201 с начальными токами стока 450, 550 и 700 мкА:
.MODEL J201_450 NJF(VTO=-0.70 BETA=1.2M LAMBDA=2M IS=114.5F RD=1 RS=1 CGD=4.667P CGS=2.992P M=.2271 PB=.5 FC=.5 VTOTC=-2.5M BETATCE=-.5 KF=604.2E-18)
.MODEL J201_550 NJF(VTO=-0.75 BETA=1.2M LAMBDA=2M IS=114.5F RD=1 RS=1 CGD=4.667P CGS=2.992P M=.2271 PB=.5 FC=.5 VTOTC=-2.5M BETATCE=-.5 KF=604.2E-18)
.MODEL J201_700 NJF(VTO=-0.85 BETA=1.2M LAMBDA=2M IS=114.5F RD=1 RS=1 CGD=4.667P CGS=2.992P M=.2271 PB=.5 FC=.5 VTOTC=-2.5M BETATCE=-.5 KF=604.2E-18)

То же для 2SK170:
.MODEL 2SK170_06MA NJF(BETA=21.8M RS=4.151 RD=4.151 BETATCE=-0.5 LAMBDA=0.0M VTO=-0.55 VTOTC=-2.5M CGD=20P M=.3805 PB=.4746 FC=.5 CGS=25.48P ISR=84.77P NR=2 IS=8.477P N=1 XTI=3 ALPHA=10U VK=100 KF=111.3E-18 AF=1)
.MODEL 2SK170_08MA NJF(BETA=24.6M RS=4.151 RD=4.151 BETATCE=-.5 LAMBDA=1.2M VTO=-0.60 VTOTC=-2.5M CGD=20P M=.3805 PB=.4746 FC=.5 CGS=25.48P ISR=84.77P NR=2 IS=8.477P N=1 XTI=3 ALPHA=10U VK=100 KF=111.3E-18 AF=1)
.MODEL 2SK170_10MA NJF(BETA=23.66M RS=4.151 RD=4.151 BETATCE=-.5 LAMBDA=13.923M VTO=-0.65 VTOTC=-2.5M CGD=20P M=.3805 PB=.4746 FC=.5 CGS=25.48P ISR=84.77P NR=2 IS=8.477P N=1 XTI=3 ALPHA=10U VK=100 KF=111.3E-18 AF=1)
.MODEL 2SK170_12MA NJF(BETA=26.49M RS=4.151 RD=4.151 BETATCE=-.5 LAMBDA=5.6M VTO=-0.70 VTOTC=-2.5M CGD=20P M=.3805 PB=.4746 FC=.5 CGS=25.48P ISR=84.77P NR=2 IS=8.477P N=1 XTI=3 ALPHA=10U VK=100 KF=111.3E-18 AF=1)
.MODEL 2SK170_20MA NJF(BETA=33.8M RS=4.151 RD=4.151 BETATCE=-.5 LAMBDA=15.0M VTO=-0.80 VTOTC=-2.5M CGD=20P M=.3805 PB=.4746 FC=.5 CGS=25.48P ISR=84.77P NR=2 IS=8.477P N=1 XTI=3 ALPHA=10U VK=100 KF=111.3E-18 AF=1)

Линейка p-канальных J17х:
.MODEL J174 PJF(VTO=-7.1 BETA=1.24461E-003 LAMBDA=2.01968E-002 RD=3.95403E+000 RS=3.95403E+000 IS=9.72750E-016 CGS=1.58000E-011 CGD=1.88000E-011 PB=3.72072E-001 FC=5.00000E-001)
.MODEL J175 PJF(VTO=-3.6 BETA=2.84523E-003 LAMBDA=2.00000E-002 RD=1.17482E+001 RS=1.17482E+001 IS=7.74158E-016 CGS=1.57000E-011 CGD=1.70000E-011 PB=3.19450E-001 FC=5.00000E-001)
.MODEL J176 PJF(VTO=-2.3 BETA=2.89414E-003 LAMBDA=2.00000E-002 RD=1.02409E+000 RS=1.02409E+000 IS=4.51393E-016 CGS=1.00000E-011 CGD=1.05000E-011 PB=7.05860E-001 FC=5.00000E-001)
.MODEL J177 PJF(VTO=-1.8 BETA=3.37432E-003 LAMBDA=2.41676E-002 RD=1.45880E+000 RS=1.45880E+000 IS=7.27555E-016 CGS=8.90000E-012 CGD=1.02500E-011 PB=6.94243E-001 FC=5.00000E-001)

.MODEL BF245A NJF(VTO=-1.7 BETA=1.16621E-003 LAMBDA=1.77211E-002 RD=9.01678E+000 RS=9.01678E+000 IS=2.91797E-016 CGS=2.20000E-012 CGD=2.20000E-012 PB=7.80988E-001 FC=5.00000E-001)
.MODEL BF245B NJF(VTO=-2.3 BETA=1.09045E-003 LAMBDA=2.31754E-002 RD=7.77648E+000 RS=7.77648E+000 IS=2.59121E-016 CGS=2.00000E-012 CGD=2.20000E-012 PB=9.91494E-001 FC=5.00000E-001)
.MODEL  BF245C NJF(VTO = -5.0014E+000 BETA = 5.43157E-004 LAMBDA = 2.71505E-002 RD = 1.20869E+001 RS = 1.20869E+001 IS = 3.64346E-016 CGS  = 2.00000E-012 CGD  = 2.00000E-012 PB = 1.24659E+000 FC = 5.00000E-001)

.MODEL 2N5457 NJF(BETA=1.125M BETATCE=-.5 RD=1 RS=1 LAMBDA=2.3M VTO=-0.6 VTOTC=-2.5M IS=181.3F ISR=1.747P N=1 NR=2 XTI=3 ALPHA=2.543U VK=152.2 CGD=4P M=.3114 PB=.5 FC=.5 CGS=4.627P KF=10.45E-18 AF=1)

.MODEL 2SK117 NJF(BETA=26.72M RS=12.31 RD=12.31 BETATCE=-.5 LAMBDA=2.462M VTO=-.8647 VTOTC=-2.5M CGD=7.762P M=.384 PB=1.153 FC=.5 CGS=14.09P ISR=112.8P NR=2 IS=11.28P N=1 XTI=3 ALPHA=10U VK=100 KF=1E-18 AF=1)
« Последняя редакция: 19.08.2012 :: 06:25:26 от lart »  

(Вложенный файл удалён)
Наверх
 
IP записан
 
access777
Полноправный участник
***
Вне Форума


GtLab.Net forever!

Сообщений: 691
Местоположение: Донецк, Украина
Зарегистрирован: 06.05.2011
Re: Библиотеки для симуляторов
Ответ #8 - 22.08.2012 :: 16:27:10
Post Tools
А есть ли модель LM386? Поделитесь, пожалуйста
« Последняя редакция: 22.08.2012 :: 16:32:42 от access777 »  

(Вложенный файл удалён)
Наверх
WWW  
IP записан
 
new_man
Гуру
*****
Вне Форума


GtLab.Net

Сообщений: 2050
Местоположение: С.-Пб.
Зарегистрирован: 18.01.2012
Re: Библиотеки для симуляторов
Ответ #9 - 22.08.2012 :: 16:37:13
Post Tools
Модель-то есть. В нете их даже несколько. Непонятно только, как ее прикрутить к лтспайсу.

.........................................................................
*TopSPICE library: Models\MISCSEMI.MDB
*PART NUMBER: LM386
*MODEL NAME:  LM386
*SYMBOL:      X8PIN
*
*LM386 Audio power amplifier
* /*
* 1.  The following model behavior shows good agreement with the
* LM386 data sheet values:
*
*   a) Quiescent power supply current;
*   b) High frequency response at low gain setting;
*   c) Power-supply rejection ratio, both bypassed and unbypassed;
*   d) Voltage gain, both with pins 1&8 shorted and open; and
*   e) Total harmonic distortion.
*
* 2.  The model has the following discrepancies:
*
*   f) High-gain frequency response looks somewhat more wideband
*      than the actual device;
*   g) Peak-to-peak output voltage swing is a bit more than the
*      data sheet value- in other words, the model drives
*      closer to the rails; and
*   h) Input bias current in this model is only about 7 nA,
*      compared with the 250 nA "typical" value mentioned in
*      the data sheet.
*
* 3.  The frequency response characteristics of this LM386 model
* can be adjusted somewhat by changing C1, the rolloff capacitor in
* the voltage gain stage.  It could also be made more realistic by
* tweaking transistor model parameters Cjc, Cje, Tr and Tf,
* although this can get pretty hairy.
*
* 4.  Likewise, output drive capability could be made more
* realistic by tweaking transistor model parameters; again, this is
* hairy.
*/
*
.subckt lm386 g1 inn inp gnd out  vs byp  g8
*             |   |   |   |   |   |   |   |
* IC pins:    1   2   3   4   5   6   7   8
* input emitter-follower buffers:
q1 gnd inn 10011 ddpnp
r1 inn gnd 50k
q2 gnd inp 10012 ddpnp
r2 inp gnd 50k
* differential input stage, gain-setting
* resistors, and internal feedback resistor:
q3 10013 10011 10008 ddpnp
q4 10014 10012 g1 ddpnp
r3 vs byp 15k
r4 byp 10008 15k
r5 10008 g8 150
r6 g8 g1 1.35k
r7 g1 out 15k
* input stage current mirror:
q5 10013 10013 gnd ddnpn
q6 10014 10013 gnd ddnpn
* voltage gain stage & rolloff cap:
q7 10017 10014 gnd ddnpn
c1 10014 10017 15pf
* current mirror source for gain stage:
i1 10002 vs dc 5m
q8 10004 10002 vs ddpnp
q9 10002 10002 vs ddpnp
* Sziklai-connected push-pull output stage:
q10 10018 10017 out ddpnp
q11 10004 10004 10009 ddnpn 100
q12 10009 10009 10017 ddnpn 100
q13 vs 10004 out ddnpn 100
q14 out 10018 gnd ddnpn 100
* generic transistor models generated
* with MicroSim's PARTs utility, using
* default parameters except Bf:
.model ddnpn NPN(Is=10f Xti=3 Eg=1.11 Vaf=100
+ Bf=400 Ise=0 Ne=1.5 Ikf=0 Nk=.5 Xtb=1.5 Var=100
+ Br=1 Isc=0 Nc=2 Ikr=0 Rc=0 Cjc=2p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1n Itf=1 Xtf=0 Vtf=10)
.model ddpnp PNP(Is=10f Xti=3 Eg=1.11 Vaf=100
+ Bf=200 Ise=0 Ne=1.5 Ikf=0 Nk=.5 Xtb=1.5 Var=100
+ Br=1 Isc=0 Nc=2 Ikr=0 Rc=0 Cjc=2p Mjc=.3333
+ Vjc=.75 Fc=.5 Cje=5p Mje=.3333 Vje=.75 Tr=10n
+ Tf=1n Itf=1 Xtf=0 Vtf=10)
.ends LM386
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
lart
Разбирающийся
****
Вне Форума



Сообщений: 1334
Зарегистрирован: 15.04.2005
Re: Библиотеки для симуляторов
Ответ #10 - 22.08.2012 :: 17:58:14
Post Tools
Прикрутить просто:
1) модель из поста new_man сохранить в папке ..\lib\sub под именем LM386.sub
2) ниже - символ LM386 (сохранить в папке ..\lib\sym под именем LM386.asy)
3) пользовать Улыбка

Version 4
SymbolType CELL
LINE Normal -32 0 64 64
LINE Normal -32 128 64 64
LINE Normal -32 0 -32 128
LINE Normal -28 32 -20 32
LINE Normal -28 96 -20 96
LINE Normal -24 100 -24 92
LINE Normal 16 0 16 32
LINE Normal -16 128 -16 117
LINE Normal -21 19 -13 19
LINE Normal -17 15 -17 23
LINE Normal -20 110 -12 110
LINE Normal 48 0 48 53
LINE Normal -16 0 -16 11
LINE Normal 32 85 32 128
LINE Normal -32 32 -48 32
LINE Normal -32 96 -48 96
LINE Normal 64 64 80 64
TEXT -49 19 Left 2 2
TEXT -49 83 Left 2 3
TEXT -9 3 Left 2 6
TEXT -9 124 Left 2 4
TEXT 19 21 Left 2 1
TEXT 52 41 Left 2 8
TEXT 35 99 Left 2 7
TEXT 62 78 Left 2 5
WINDOW 0 64 16 Left 2
WINDOW 3 48 120 Left 2
SYMATTR Value LM386
SYMATTR Prefix X
SYMATTR SpiceModel LM386.sub
SYMATTR Value2 LM386
SYMATTR Description Audio Power Amplifier
PIN 16 0 NONE 0
PINATTR PinName g1
PINATTR SpiceOrder 1
PIN -48 32 NONE 0
PINATTR PinName inn
PINATTR SpiceOrder 2
PIN -48 96 NONE 0
PINATTR PinName inp
PINATTR SpiceOrder 3
PIN -16 128 NONE 0
PINATTR PinName gnd
PINATTR SpiceOrder 4
PIN 80 64 NONE 0
PINATTR PinName out
PINATTR SpiceOrder 5
PIN -16 0 NONE 0
PINATTR PinName vs
PINATTR SpiceOrder 6
PIN 32 128 NONE 8
PINATTR PinName byp
PINATTR SpiceOrder 7
PIN 48 0 NONE 0
PINATTR PinName g8
PINATTR SpiceOrder 8
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
new_man
Гуру
*****
Вне Форума


GtLab.Net

Сообщений: 2050
Местоположение: С.-Пб.
Зарегистрирован: 18.01.2012
Re: Библиотеки для симуляторов
Ответ #11 - 22.08.2012 :: 18:14:32
Post Tools
lart
Спасибо!
Улыбка
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
access777
Полноправный участник
***
Вне Форума


GtLab.Net forever!

Сообщений: 691
Местоположение: Донецк, Украина
Зарегистрирован: 06.05.2011
Re: Библиотеки для симуляторов
Ответ #12 - 22.08.2012 :: 19:11:43
Post Tools
Спасибо и от меня тоже Улыбка
  

(Вложенный файл удалён)
Наверх
WWW  
IP записан
 
new_man
Гуру
*****
Вне Форума


GtLab.Net

Сообщений: 2050
Местоположение: С.-Пб.
Зарегистрирован: 18.01.2012
Re: Библиотеки для симуляторов
Ответ #13 - 23.08.2012 :: 18:11:35
Post Tools
Забавно. Модель 386 имеет такой-же кривой выход (5.7В вместо 4.5В), как и некоторые реальные ее собратья. Только, в отличие от них, симметрироваться не хочет ни в какую. Кривая модель, что ли?
Схема включения КДМ, если что.
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #14 - 23.08.2012 :: 19:01:31
Post Tools
А чем ты её симметрируешь то? Озадачен
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
new_man
Гуру
*****
Вне Форума


GtLab.Net

Сообщений: 2050
Местоположение: С.-Пб.
Зарегистрирован: 18.01.2012
Re: Библиотеки для симуляторов
Ответ #15 - 23.08.2012 :: 19:09:13
Post Tools
Peratron писал(а) 23.08.2012 :: 19:01:31:
А чем ты её симметрируешь то? Озадачен

А почитай топик про КДМ. Там все-все написано. Улыбка
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #16 - 23.08.2012 :: 20:24:46
Post Tools
А кто сказал, что обсуждённое там реально симметрирует?
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Denn
Модератор
*****
Вне Форума


είμαι ο μουσικός και ο
ραδιομηχανίκός

Сообщений: 14276
Местоположение: Θεσσαλoνiκη
Зарегистрирован: 14.03.2006
Re: Библиотеки для симуляторов
Ответ #17 - 25.08.2012 :: 20:57:37
Post Tools
Тема почищена от оффтопа.
  

(Вложенный файл удалён)

Не говорите что мне делать, и я не скажу куда Вам идти.

Лучшее решение из возможных - самое простое. И наоборот.

Прежде чем судить меня, убедитесь, что вы совершенны.
Наверх
ICQ  
IP записан
 
new_man
Гуру
*****
Вне Форума


GtLab.Net

Сообщений: 2050
Местоположение: С.-Пб.
Зарегистрирован: 18.01.2012
Re: Библиотеки для симуляторов
Ответ #18 - 26.08.2012 :: 04:10:20
Post Tools
Есть следующие вопросы к знатокам симуляции.

На сайтах некоторых производителей лежат модели в разных вариантах, наверно под разные софтины. Встречаются названия Spice2, Spice3, PSpice, Saber. Соответственно и файлы с разными расширениями: .lib, .sin, .sp2, .sp3, и так далее.

Вопрос 1. Какие из перечисленных файлов подходят для LTspice непосредственно?
Вопрос 2. Можно ли подточить напильником неродной файл, чтобы подошел для LTspice? Если да, то что конкретно нужно сделать для того?
Вопрос 3. Что нужно прочитать НА РУССКОМ, чтобы перестать уже задавать дурацкие вопросы?

  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #19 - 26.08.2012 :: 08:40:17
Post Tools
.lib - это каноническое расширение для PSpice.
Остальные спайсы - производные от него.
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
lart
Разбирающийся
****
Вне Форума



Сообщений: 1334
Зарегистрирован: 15.04.2005
Re: Библиотеки для симуляторов
Ответ #20 - 09.10.2012 :: 04:26:34
Post Tools
Модель для 2SJ162 (комплементарна 2SK1058)

.MODEL 2SJ162 PMOS (VTO=842.193M KP=20U L=2U W=21.3317M GAMMA=0 PHI=600M LAMBDA=20.7067M RD=837.199M CBD=2.96862N IS=10F CGSO=1.13517N CGDO=1.13517N TOX=0 NSUB=0 TPG=1 UO=600 RG=50 RDS=1MEG )
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Elick
Участник


Re: Библиотеки для симуляторов
Ответ #21 - 12.10.2012 :: 00:05:50
Post Tools
Перенёс просьбу в другую тему, как это сообщение удалить не нашёл...  Улыбка
« Последняя редакция: 12.10.2012 :: 12:08:22 от »  

(Вложенный файл удалён)
Наверх
 
IP записан
 
access777
Полноправный участник
***
Вне Форума


GtLab.Net forever!

Сообщений: 691
Местоположение: Донецк, Украина
Зарегистрирован: 06.05.2011
Re: Библиотеки для симуляторов
Ответ #22 - 15.10.2012 :: 15:34:29
Post Tools
  

(Вложенный файл удалён)
Наверх
WWW  
IP записан
 
Elick
Участник


Re: Библиотеки для симуляторов
Ответ #23 - 21.10.2012 :: 18:35:14
Post Tools
new_man писал(а) 26.08.2012 :: 04:10:20:
Есть следующие вопросы к знатокам симуляции.

На сайтах некоторых производителей лежат модели в разных вариантах, наверно под разные софтины. Встречаются названия Spice2, Spice3, PSpice, Saber. Соответственно и файлы с разными расширениями: .lib, .sin, .sp2, .sp3, и так далее.

Вопрос 1. Какие из перечисленных файлов подходят для LTspice непосредственно?
Вопрос 2. Можно ли подточить напильником неродной файл, чтобы подошел для LTspice? Если да, то что конкретно нужно сделать для того?
Вопрос 3. Что нужно прочитать НА РУССКОМ, чтобы перестать уже задавать дурацкие вопросы?



1. Lib подходит. Из названий я подключаю текстовые файлы Spice2.
2. Точить можно, но я этим не занимался, т.к. камрад Lart доходчиво объяснил что и как искать, и чуть выше как вставлять.
3. Камрад TrueVAL поделился со мной литературой по этой теме. Не думаю, что там есть секретные материалы, поэтому тут. http://www.onlinedisk.ru/file/965761/
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Elick
Участник


Re: Библиотеки для симуляторов
Ответ #24 - 31.10.2012 :: 12:19:27
Post Tools
Набрёл, мож кому пригодится...
http://www.madlabo.com/mad/edat/spice/model/index.htm
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Elick
Участник


Re: Библиотеки для симуляторов
Ответ #25 - 07.11.2012 :: 19:15:51
Post Tools
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Moonlight
Разбирающийся
****
Вне Форума


GTLab - forever!

Сообщений: 1457
Местоположение: Киев
Зарегистрирован: 27.08.2009
Re: Библиотеки для симуляторов
Ответ #26 - 08.11.2012 :: 22:53:03
Post Tools
Понадобился мне драйвер ucc37322, погуглив обнаружил форум http://www.offtop.ru/gauss2k/v7_696421_1.php?of991=g61thl06k9s655qpv4fqidkpp4 но так и не разобрался как это засунуть в свкад. Нарисовал корпус с ножками, сделал файл .lib но в итоге ничего не происходит. Может кто умеет это делать и поможет мне запустить модельку?
  

(Вложенный файл удалён)

"-Скажи волшебное слово.
-Rock-n-Roll, чувак!"
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #27 - 09.11.2012 :: 09:28:48
Post Tools
@ Moonlight

Плз, перенеси обсуждение в другую тему - пусть эта останется только для размещения библиотек или ссылок на источники оных...
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Elick
Участник


Re: Библиотеки для симуляторов
Ответ #28 - 11.12.2012 :: 19:08:07
Post Tools
Господа, есть у кого моделька для 2SJ308. Очень надо. Поиском не решил, поможите, плиз... Круглые глаза

Изменено:
Не знаю, было или нет, модели от IR
http://www.irf.com/product-info/models/model_links.html
« Последняя редакция: 12.12.2012 :: 20:51:35 от »  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Elick
Участник


Re: Библиотеки для симуляторов
Ответ #29 - 08.03.2013 :: 19:07:14
Post Tools
« Последняя редакция: 08.03.2013 :: 19:10:43 от »  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
CD4053 spice model wanted
Ответ #30 - 19.04.2013 :: 06:52:55
Post Tools
Ну, очень хочется 4053, но до кучи приму с благодарностью и прочие аналоговые КМОП-ключи из 4000 серии.
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
PSPICE Calc V1.2 Triode Calculator
Ответ #31 - 19.11.2013 :: 21:35:30
Post Tools
http://www.chemroc.com/PSPICE.html

Калькулятор, создающий спайс-модель лампового триода по картинке ВАХ.
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #32 - 06.05.2014 :: 22:09:25
Post Tools
Ищется адекватная модель 2N7000.

Обычно этот транзистор имеется в штатных библиотеках - по крайней мере в ОрКАДе и в ПРОТЕУСе оно есть.

Но что-то ВАХи реальных камней не сходятся с модельными.
При том, что данные из мануалов, причём, от разных производителей, гораздо ближе к реальности (плюс/минус немалый производственный разброс, конечно).

ХИНТ: в первую очередь интересны характеристики при малых токах - в единицы мА.
То есть, на пороге открывания.

Кто нибудь правильной моделькой располагает?

Конечно, если припрёт - придётся садиться и лепить самому.
Но, блин, лениво ж!
Ну, неужто на это сверхизвестное ... нет правильной модели?!
Ужас
« Последняя редакция: 06.05.2014 :: 22:10:03 от Peratron »  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
lart
Разбирающийся
****
Вне Форума



Сообщений: 1334
Зарегистрирован: 15.04.2005
Re: Библиотеки для симуляторов
Ответ #33 - 07.05.2014 :: 18:11:17
Post Tools
Если я правильно понимаю, 2N7002 - это тот же 2N7000, но в SMD упаковке.
В штатной библиотеке LTSpice имеется вот такая модель:

.model 2N7002 VDMOS(Rg=3 Vto=1.6 Rd=0 Rs=.75 Rb=.14 Kp=.17 mtriode=1.25 Cgdmax=80p Cgdmin=12p Cgs=50p Cjo=50p Is=.04p mfg=Fairchild Vds=60 Ron=2 Qg=1.5n)
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
Re: Библиотеки для симуляторов
Ответ #34 - 07.05.2014 :: 18:17:55
Post Tools
Псб.
Попробую.
Но 7002 есть в библиотеках, как и 7000 - тоже с какими то левыми характеристиками...
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Vitalka
Гуру
*****
Вне Форума



Сообщений: 1748
Местоположение: Млинів
Зарегистрирован: 30.09.2008
Re: Библиотеки для симуляторов
Ответ #35 - 18.07.2016 :: 20:10:04
Post Tools
Peratron писал(а) 19.11.2013 :: 21:35:30:
http://www.chemroc.com/PSPICE.html

Калькулятор, создающий спайс-модель лампового триода по картинке ВАХ.


Какие требования по разрешению к картинке? А то с триодной части 6ф1п модель сделать не получается что-то вообще
  

(Вложенный файл удалён)

Мои соседи слушают офигенные песни, и мне все равно, хотят они этого или нет
Наверх
IP записан
 
Peratron
Гуру
*****
Вне Форума


GTLab - forever!

Сообщений: 13579
Зарегистрирован: 16.08.2009
TL431+
Ответ #36 - 27.03.2017 :: 09:06:16
Post Tools
* TL431
*****************************************************************************
* (C) Copyright 2009 Texas Instruments Incorporated. All rights reserved.                                           
*****************************************************************************
** This model is designed as an aid for customers of Texas Instruments.                                             
** TI and its licensors and suppliers make no warranties, either expressed                                          
** or implied, with respect to this model, including the warranties of                                                   
** merchantability or fitness for a particular purpose. The model is                                                      
** provided solely on an "as is" basis. The entire risk as to its quality                                                   
** and performance is with the customer                                                                                             
*****************************************************************************
*
* This model was developed for Texas Instruments Incorporated by:
*   AEi Systems, LLC
*   5777 W. Century Blvd., Suite 876
*   Los Angeles, California  90045
*
* This model is subject to change without notice. Neither Texas Instruments Incorporated
* nor AEi Systems is responsible for updating this model.
* For more information regarding modeling services, model libraries and simulation
* products, please call AEi Systems at (310) 216-1144, or contact AEi Systems by email:
* info@AENG.com. Or visit AEi Systems on the web at http://www.AENG.com.
*
*****************************************************************************
*
** Released by: Analog eLab Design Center, Texas Instruments Inc.
* Part: TL431
* Date: 12/14/2009
* Model Type: Transient and AC 
* Simulator: PSPICE 
* Simulator Version: 16.0.0.p001
* Datasheet: SLVS543J - AUGUST 2004 - REVISED DECEMBER 2005
*
*****************************************************************************
*
* Updates:
*
* Final 2.00
* Changed encrypted model to unencrypted.
*
* Final 1.00
* Release to Web.
*
*****************************************************************************
.SUBCKT TL431+ 7 6 11
*             K A FDBK
V1 1 6 2.495
R1 6 2 15.6
C1 2 6 .5U
R2 2 3 100
C2 3 4 .08U
R3 4 6 10
GB1 6 8 VALUE = {IF(V(3,6)< 0 , 1.73*V(3,6) -1U , -1U)}
D1 5 8 DCLAMP
D2 7 8 DCLAMP
V4 5 6 2
G1 6 2 1 11 0.11
.MODEL DCLAMP D (IS=13.5N RS=25M N=1.59
+ CJO=45P VJ=.75 M=.302 TT=50.4N BV=34V IBV=1MA)
.ENDS
  

(Вложенный файл удалён)

Схемотехническая мантра: титцешенкохоровицехилл. Повторять до просветления...
Наверх
 
IP записан
 
Добрый Кот
Модератор
*****
Вне Форума


GtLab.Net forever!

Сообщений: 1030
Местоположение: Невыносимовск
Зарегистрирован: 25.08.2016
Re: Библиотеки для симуляторов
Ответ #37 - 12.04.2017 :: 14:41:13
Post Tools
Добрый день.
Есть у кого нибудь спайс модель 6С19П, поделитесь пожалуйста.
  

(Вложенный файл удалён)
Наверх
 
IP записан
 
Jinx
Гуру
*****
Вне Форума



Сообщений: 4123
Местоположение: Москва
Зарегистрирован: 02.01.2008
Re: Библиотеки для симуляторов
Ответ #38 - 08.05.2018 :: 11:20:57
Post Tools
@ Добрый Кот

Можете взять мою общую модель и адаптировать по ВАХ из паспорта. ECC83 для примера есть.

Код
Select All
*******************************************************************************
* Generic thermionic triode valve model with improved grid current, low mu at *
* high Va, and kinked positive grid voltage curves.                           *
* Copyright (c) Orson J. Maxwell 2018                                         *
*******************************************************************************
.SUBCKT THERMTRIODE A G C
+ PARAMS: MU=100 EX=1.4 KG1=900 KP=600 KVB=300; Koren params w/o RGI
+ GO=0.6 ; Grid offset - helps model increased Ia on low Va
+ CCG=3.8P CGA=0.05P CCA=5.3P ; Interelectrode capacitances
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5 ; Grid current offset, proportion, and magnitude
* Anode current
Eanode  7 0 VALUE=
+{V(A,C)/KP*LOG(1+EXP(KP*(1/MU+(V(G,C)+{GO})/SQRT(KVB+V(A,C)*V(A,C)))))}
REanode 7 0 1G
Ganode  A C VALUE={PWR(V(7),EX)/KG1}
Rac     A C 1G    ; Tie floating nodes
* Interelectrode capacitances
Cgc     G C {CCG} ; Cathode-grid capacitance
Cga     G A {CGA} ; Grid-anode capacitance
Cca     A C {CCA} ; Cathode-anode capacitance
* Grid current
Ggrid   G C VALUE=
+{PWR(LIMIT{V(G,C)-{GCO},0,1E6},{GCP})*({GCM}+((300-V(A,C))/2e6))}
.ENDS
*******************************************************************************

.SUBCKT ECC83JCA A G C
XV1 A G C THERMTRIODE
+ PARAMS: MU=100 EX=1.4 KG1=900 KP=600 KVB=300 GO=0.6
+ CCG=1.6P CGA=1.7P CCA=.33P
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5
.ENDS ECC83JCA 



Раз пошла такая пьянка, то приеду домой и общую модель пентода, включенного как тетрод тоже положу. Модель менее перегружена (быстрее симулируется), чем та, что от Дункана Манро, но и не валит SPICE движок на перегрузе во временном домене, как например модель Нормана Корена.

« Последняя редакция: 08.05.2018 :: 14:08:39 от Jinx »  

Если хочешь, чтобы что-то было сделано хорошо - сделай сам.
R2DNY
Наверх
GTalk  
IP записан
 
Jinx
Гуру
*****
Вне Форума



Сообщений: 4123
Местоположение: Москва
Зарегистрирован: 02.01.2008
Re: Библиотеки для симуляторов
Ответ #39 - 08.05.2018 :: 14:11:34
Post Tools
Код
Select All
*******************************************************************************
* Generic thermionic pentode valve model with improved grid current, screen   *
* grid complimentary current and realistic curve clamping.                    *
* Copyright (c) Orson J. Maxwell 2018                                         *
*******************************************************************************
.SUBCKT THERMPENTODE A G C S
+ PARAMS: MU=56 EX=1.35 KG1=630 KG2=4800 KP=110 KVB=9; Koren params /o RGI
+ TCC=1e-4 ; Transconductance curve tilt
+ CCG=4P CGA=5.5P CCA=.33P ; Interelectrode capacitances
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5 ; Grid current offset, proportion, and magnitude
* Anode current
RE1 7 0 1G
E1 7 0 VALUE=
+{V(S,C)/KP*LOG(1+EXP((1/MU+V(G,C)/V(S,C))*KP))+V(A,C)*{TCC}}
Ganode  A C VALUE={PWR(V(7),EX)/KG1*ATAN(V(A,C)/KVB)}
*Gscreen S C VALUE={PWR((V(S,C)/MU+V(G,C)),EX)/KG2}
Etotal  8 0 VALUE={PWR(V(7),EX)/KG2}
Gscreen S C VALUE={V(8)-I(GANODE)}
Rac     A C 1G    ; Tie floating nodes
* Interelectrode capacitances
Cgc     G C {CCG} ; Cathode-grid capacitance
Cga     G A {CGA} ; Grid-anode capacitance
Cca     A C {CCA} ; Cathode-anode capacitance
* Grid current
Ggrid   G C VALUE=
+{PWR(LIMIT{V(G,C)-{GCO},0,1E6},{GCP})*({GCM}+((300-V(A,C))/2e6))}
.ENDS
*******************************************************************************

.SUBCKT EF86JCA A G C S
XV1 A G C S THERMPENTODE
+ PARAMS: MU=56 EX=1.35 KG1=630 KG2=340 KP=110 KVB=9 TCC=1e-4
+ CCG=1.6P CGA=1.7P CCA=.33P
+ GCO=-0.9 GCP=2.5 GCM=5.4e-5
.ENDS EF86JCA 

  

Если хочешь, чтобы что-то было сделано хорошо - сделай сам.
R2DNY
Наверх
GTalk  
IP записан
 
 
  « Главная ‹ Раздел Наверх этой страницы