На самом деле доступны параметры транзисторов старого техпроцесса NXP, по которому делается серия 74HCxxx.
В частности - классика жанра, 74HCU04 - шесть инверторов без буферизации:
********* HCU04 SUBCIRCUIT ****************************************
**** RUNS ON PSpice, MAY NEED MODIFICATION FOR OTHER PLATFORMS ****
****** NODES: INPUT OUTPUT VDD ***********************************
.SUBCKT XHCU04 2 3 1
MU 3 2 1 1 P1JT L=1.76u W=654U AD=5559P AS=5559P PD=1325U PS=1325U
+ NRD=6.116m NRS=6.116m
ML 3 2 0 0 N1JT L=1.76u W=182U AD=1547P AS=1547P PD=381U PS=381U NRD=22m
+ NRS=22m
.MODEL N1JT NMOS
+ LEVEL = 3
+ NSS = 0.00000E+00 VTO = 8.00000E-01 TOX = 2.30000E-08
+ XJ = 7.47842E-08 LD = 0.04500E-06 RSH = 65
+ NSUB = 2.77696E+16 NFS = 1.26234E+11 UO = 5.82719E+02
+ VMAX = 2.65458E+05 DELTA = 8.81407E-01 THETA = 5.29522E-02
+ ETA = 3.52580E-02 KAPPA = 2.15314E-01
+ CGSO = 6.75E-11 CGDO = 6.75E-11 CGBO = 0.00
+ CJ = 3.82E-04 CJSW = 1.25E-09 PB = 1.231
+ MJ = 0.396 MJSW = 0.221 TPG = 1
+ DW =-0.46000E-06 DL =-0.42000E-06
+ XQC = 1
*
.MODEL P1JT PMOS
+ LEVEL = 3
+ NSS = 0.00000E+00 VTO =-9.00000E-01 TOX = 2.30000E-08
+ XJ = 8.32522E-08 LD = 0.03500E-06 RSH = 125
+ NSUB = 1.33990E+16 NFS = 7.19190E+11 UO = 1.92014E+02
+ VMAX = 4.16775E+07 DELTA = 5.63546E-01 THETA = 1.22160E-01
+ ETA = 4.96427E-02 KAPPA = 5.00000E-02
+ CGSO = 5.25E-11 CGDO = 5.25E-11 CGBO = 0.00
+ CJ = 4.01E-04 CJSW = 1.237E-09 PB = 0.723
+ MJ = 0.452 MJSW = 0.186 TPG = -1
+ DW =-0.46000E-06 DL =-0.44000E-06
+ XQC = 1
.ENDS XHCU04
На самом деле полная модель немного сложнее, но для не слишком ВЧ годится и такой упрощенный вариант. Только очень желательно заменить непосредственное соединение с GND (узел 0) на обычный вывод.
...
* IN OUT VDD VSS
.SUBCKT XHCU04 2 3 1 4
MU 3 2 1 1 P1JT L=1.76u W=654U AD=5559P AS=5559P PD=1325U PS=1325U
+ NRD=6.116m NRS=6.116m
ML 3 2 4 4 N1JT L=1.76u W=182U AD=1547P AS=1547P PD=381U PS=381U NRD=22m
+ NRS=22m
...
Можно найти и модели ключей. Вот, собственно, его нутро:
************************************************
* NOMINAL N-Channel Transistor *
* UCB-3 Parameter Set *
* HIGH-SPEED CMOS Logic Family *
* 10-Jan.-1995 *
************************************************
.Model MHCNEN NMOS
+LEVEL = 3
+KP = 45.3E-6
+VTO = 0.72
+TOX = 51.5E-9
+NSUB = 2.8E15
+GAMMA = 0.94
+PHI = 0.65
+VMAX = 150E3
+RS = 40
+RD = 40
+XJ = 0.11E-6
+LD = 0.52E-6
+DELTA = 0.315
+THETA = 0.054
+ETA = 0.025
+KAPPA = 0.0
+WD = 0.0
***********************************************
* NOMINAL P-Channel transistor *
* UCB-3 Parameter Set *
* HIGH-SPEED CMOS Logic Family *
* 10-Jan.-1995 *
***********************************************
.Model MHCPEN PMOS
+LEVEL = 3
+KP = 22.1E-6
+VTO = -0.71
+TOX = 51.5E-9
+NSUB = 3.3E16
+GAMMA = 0.92
+PHI = 0.65
+VMAX = 970E3
+RS = 80
+RD = 80
+XJ = 0.63E-6
+LD = 0.23E-6
+DELTA = 2.24
+THETA = 0.108
+ETA = 0.322
+KAPPA = 0.0
+WD = 0.0
.SUBCKT SWITCH1N 2 8 9 40 50
* ANALOG SWITCH
* INPUT = 2, Y = 8, Z = 9, VEE = 40, VCC =50
MP1 3 2 50 50 MHCPEN W= 88U L=2.4U AD= 350P AS= 350P PD=100U PS= 88U
MN1 3 2 40 40 MHCNEN W= 56U L=2.4U AD= 225P AS= 225P PD= 70U PS= 56U
MP4 4 3 50 50 MHCPEN W= 350U L=2.4U AD= 900P AS= 900P PD=200U PS= 350U
MN4 4 3 40 40 MHCNEN W= 150U L=2.4U AD= 400P AS= 400P PD=100U PS= 150U
MP5 8 4 5 50 MHCPEN W= 216U L=2.4U AD= 900P AS= 900P PD=100U PS= 216U
MN5 8 3 5 5 MHCNEN W= 108U L=2.4U AD= 430P AS= 430P PD= 50U PS= 108U
MN6 5 4 40 40 MHCNEN W= 145U L=2.4U AD= 600P AS= 600P PD= 75U PS= 145U
MP7 9 4 8 50 MHCPEN W=1068U L=2.4U AD=2500P AS=2500P PD= 10U PS=1068U
MN7 9 3 8 5 MHCNEN W= 312U L=2.4U AD=1200P AS=1200P PD= 10U PS= 312U
.ENDS
Короче, кто ищет - тот всегда найдет.